nixos-config/flake.nix

{
  inputs = {
    nixos-hardware.url = "github:nixos/nixos-hardware";
    utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    artemist = {
      url = "git+https://git.mildlyfunctional.gay/artemist/packages.git";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.utils.follows = "utils";
    };
    fonts = {
      url = "git+https://git.mildlyfunctional.gay/artemist/fonts.git";
      inputs.artemist.follows = "artemist";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "utils";
    };
    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.3.0";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "utils";
    };
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixvim = {
      url = "github:nix-community/nixvim";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.home-manager.follows = "home-manager";
      inputs.nix-darwin.follows = "";
    };
    nix-index-database = {
      url = "github:nix-community/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    rustybar = {
      url =
        "git+https://git.mildlyfunctional.gay/mildlyfunctionalgays/rustybar.git";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.utils.follows = "utils";
    };
    jovian = {
      url = "github:jovian-experiments/jovian-nixos";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.nix-github-actions.follows = "";
    };

    private.url =
      "git+ssh://forgejo@git.mildlyfunctional.gay/artemist/nixos-config-private?ref=unified";
  };

  outputs = { self, nixpkgs, home-manager, utils, nixvim, ... }@inputs:
    let
      baseDir = ./system;
      lib = nixpkgs.lib;
      makeSystem = module:
        lib.nixosSystem (rec {
          specialArgs = { inherit inputs; };
          modules = [
            home-manager.nixosModules.home-manager
            { home-manager.extraSpecialArgs = specialArgs; }
          ] ++ [ module ];
        });
    in {
      nixosConfigurations =
        lib.mapAttrs (name: _: makeSystem (baseDir + "/${name}"))
        (builtins.readDir baseDir);
    } // utils.lib.eachDefaultSystem (system:
      let pkgs = import nixpkgs { inherit system; };
      in {
        formatter = pkgs.nixfmt;
        packages = {
          nvim = inputs.nixvim.legacyPackages."${system}".makeNixvimWithModule {
            extraSpecialArgs = { inherit inputs; };
            module = import ./sets/nvim.nix {
              path = [ ];
              inherit (pkgs) lib;
            };
          };
        };
      });
}